% Filename: rfcmrm.mf
% Author: Alan Jeffrey
% E-mail: jeffrey@cs.chalmers.se
% Version number: 1.0
% Last modified: 18 Dec 1991

% 18 Dec 1991: Finished V1.0

% These are the extra glyphs for my proposed TeX math font scheme.

mode_setup; font_setup;

% The Greek glyphs, upright.

input greeku;
input greekl;

% Some characters from msbm (the only change is that they are now upright).

beginchar(oct"050", 12u#, x_height#, 0);
italcorr 1/3x_height#*slant+.5hair#+.5u#;
adjust_fit(0,0); pickup rule.nib;
pos1(stem,0); pos2(stem,0);x1l=hround(2u-.5stem); x2r=w-x1l;
top y2+.3stem=h+oo; bot y1-.3stem=-oo;
filldraw z1l---z2l...z2r---z1r...cycle;
pickup crisp.nib;
pos3(hair,180); x3=lft x1l; y3=3/4h; pos4(stem,90); 
top y4r+.15stem=h+oo; x4-x3=.05[x1,x2]; 
pos4'(hair,0); y4'=y3; x4'=1/4[x1,x2];
pos5(hair,90); z5=z1; 
filldraw super_arc.r(3,4)&super_arc.r(4,4')...{z1-z2}z5&z5{z2-z1}
...super_arc.l(4',4)&super_arc.l(4,3)---cycle; % left arm
pos8(hair,-90); pos6(hair,0);                     
z8=z2; pos7(stem, -90); bot y7r-.15stem=-oo; x6-x7=x4-x3;
x6=w-x3; 
pos7'(hair,180); y7'=y6; x7'=w-x4';
y6=h-y3;
filldraw super_arc.r(6,7)&super_arc.r(7,7')...{z2-z1}z8&z8{z1-z2}
...super_arc.l(7',7)&super_arc.l(7,6)---cycle; % right arm
%filldraw z8{z1-z2}..z7l...{up}z6r---z6l{-u,-2u}...z7r..{z2-z1}z8---cycle; %right arm
penlabels(range 1 thru 8,4'); endchar;

cmchar "Reversed, reflected, lowercase Greek epsilon";
beginchar(oct"051",8u#,x_height#,0);
italcorr x_height#*slant+.5hair#-2u#;
adjust_fit(0,0); pickup fine.nib;
pos0(bar,90); pos1(bar,90); pos2(curve,180);
pos3(vair,270); pos4(hair,300); pos6(bar,90); pos7(bar,90);
x1=.5w+.5u; x0=x1+u; lft x2r=hround(1.5u-.5curve); x3=.5[x0,x1];
x4r=good.x(w-u); x5=w+.5u; x6=x0; z7=z2l;
top y0r=top y1r=h; y2=y5=y6=bar_height; bot y3r=-oo;
path p; p=z3r{right}...{up}z5;
numeric t; t=ypart(((x4r,y3r)--(x4r,y5))intersectiontimes p);
y4r=ypart point t of p;
filldraw circ_stroke z0e..pulled_arc.e(1,2) & pulled_arc.e(2,3)
 ...z4e{direction t of p};  % arc
filldraw circ_stroke z6e--z7e;  % bar
math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
picture v;
v:=currentpicture; 
v:=v reflectedabout((0,h/2),(w,h/2)); 
v:=v reflectedabout((w/2,-d),(w/2,h)); 
currentpicture:=v shifted (2u,0);
penlabels(0,1,2,3,4,5,6,7); endchar;

% Some hacked-around cmr characters.

cmchar "h with horizontal stroke";
beginchar(oct"052",10u#,asc_height#,0);
italcorr .5[bar_height#,x_height#]*slant-serif_fit#+.5stem#-2u#;
adjust_fit(serif_fit#+stem_shift#,serif_fit#-stem_shift#);
pickup tiny.nib; pos1(stem,0); pos2(stem,0);
pos1'(stem',0); pos2'(stem',0); pos3(stem,0);
lft x1l=hround(2.5u-.5stem); x1l=x1'l=x2l=x2'l; x3=w-x1;
top y1=h; bot y2=0; y1=y1'; y2=y2';
filldraw stroke z1'e--z2'e;  % left stem
h_stroke(2,a,3,4);  % arch and right stem
if serifs: sloped_serif.l(1',2',b,1/3,jut,serif_drop); % upper left serif
 numeric inner_jut; pickup tiny.nib;
 if rt x2r+jut+.5u+1<=lft x4l-jut: inner_jut=jut;
 else: rt x2r+jut+.5u+1=lft x4l-inner_jut; fi
 dish_serif(2,1,c,1/3,jut,d,1/3,jut); % lower left serif
 dish_serif(4,3,e,1/3,inner_jut,f,1/3,jut); fi % lower right serif
 pickup crisp.nib; x5=x2l-2u; x6=x2r+2u; % STROKE!
 y5=y6=.4[x_height,h]; draw z5--z6;   % STROKE!
penlabels(1,2,3,4,5,6); endchar;

cmchar "h with diagonal stroke";
beginchar(oct"053",10u#,asc_height#,0);
italcorr .5[bar_height#,x_height#]*slant-serif_fit#+.5stem#-2u#;
adjust_fit(serif_fit#+stem_shift#,serif_fit#-stem_shift#);
pickup tiny.nib; pos1(stem,0); pos2(stem,0);
pos1'(stem',0); pos2'(stem',0); pos3(stem,0);
lft x1l=hround(2.5u-.5stem); x1l=x1'l=x2l=x2'l; x3=w-x1;
top y1=h; bot y2=0; y1=y1'; y2=y2';
filldraw stroke z1'e--z2'e;  % left stem
h_stroke(2,a,3,4);  % arch and right stem
if serifs: sloped_serif.l(1',2',b,1/3,jut,serif_drop); % upper left serif
 numeric inner_jut; pickup tiny.nib;
 if rt x2r+jut+.5u+1<=lft x4l-jut: inner_jut=jut;
 else: rt x2r+jut+.5u+1=lft x4l-inner_jut; fi
 dish_serif(2,1,c,1/3,jut,d,1/3,jut); % lower left serif
 dish_serif(4,3,e,1/3,inner_jut,f,1/3,jut); fi % lower right serif
 pickup crisp.nib; x5=x2l-2u; x6=x2r+2u; % STROKE!
 .5[y5,y6]=.4[x_height,h]; y6-y5=2u; draw z5--z6;   % STROKE!
penlabels(1,2,3,4,5,6); endchar;

cmchar "Cents";
beginchar(oct"054",8u#,x_height#,0);
italcorr x_height#*slant-.2u#;
adjust_fit(if monospace: .5u#,.5u# else: 0,0 fi);
pickup fine.nib; pos2(vair',90); pos4(vair',270);
x2=x4=.5(w+u); top y2r=vround(h+1.5oo); bot y4r=-oo;
pos3(curve,180); lft x3r=hround max(.6u,1.35u-.5curve); y3=.5h;
if serifs: pos1(hair,0); pos0(flare,0);
 y1=min(bar_height+.5flare+2vair'+2,.9[bar_height,h]-.5flare);
 rt x1r=hround(w-.7u); bulb(2,1,0);  % bulb
 pos5(hair,0); rt x5r=hround(w-.5u);
 y5=max(good.y(.5bar_height-.9),y4l+vair');
 (x,y4l)=whatever[z4r,z5l]; x4l:=min(x,x4l+.5u);
 filldraw stroke pulled_super_arc.e(2,3)(.7superpull)
  & pulled_super_arc.e(3,4)(.5superpull)
  ..tension .9 and 1..{x5-x4,5(y5-y4)}z5e;  % arc and lower terminal
else: pos1(4/7[vair',flare],80);
 rt x1r=hround(w-.6u); top y1r=vround .82[bar_height,top y2r];
 filldraw stroke term.e(2,1,right,.8,4);  % upper terminal
 pos5(.6[vair',flare],275); rt x5r=hround(w-.5u);
 y5r=good.y(y5r+1/3bar_height-y5); y5l:=good.y y5l; x5l:=good.x x5l;
 forsuffixes e=l,r: path p.e; p.e=z4e{right}..tension .9 and 1..z5e;
  if angle direction 1 of p.e>75:
   p.e:=z4e{right}..tension atleast.9 and 1..{dir 75}z5e; fi endfor
 filldraw stroke pulled_super_arc.e(2,3)(.7superpull)
  & pulled_super_arc.e(3,4)(.5superpull) & p.e; fi  % arc and lower terminal
 pickup crisp.nib; x6=x7=x2; y6=h+1.5u; y7=-1.5u; draw z6--z7; % STROKE!
penlabels(0,1,2,3,4,5,6,7); endchar;

cmchar "Currency symbol";
beginarithchar(oct"055"); pickup rule.nib; autocorrection:=1;
x1=good.x(1/sqrt2)[.5w,rt u]; y1=good.y(1/sqrt2)[math_axis,bot h];
x2=x3=w-x1; x4=x1; .5[y1,y2]=.5[y3,y4]=math_axis; y2=y4;
z5=.25[z1,z2]; z6=.25[z3,z4]; z7=.25[z2,z1]; z8=.25[z4,z3];
draw z1--z5; draw z2--z7; draw z3--z6; draw z4--z8; % tails
draw z5..z6..z7..z8..cycle; % circle
labels(1,2,3,4,5,6,7,8); endchar;

cmchar "Left semantic bracket [[";
beginchar(oct"056",7.25u#,body_height#,paren_depth#);
adjust_fit(0,0);
pickup crisp.nib; pos1(rule_thickness,0); pos2(rule_thickness,0);
top y1=h; bot y2=-d; lft x1l=lft x2l=hround(2.5u-.5rule_thickness)-1-eps;
filldraw stroke z1e--z2e;  % left stem
pos7(rule_thickness,0); pos8(rule_thickness,0);
top y7=h; bot y8=-d; lft x7l=lft x8l=hround(4.75u-.5rule_thickness)-1-eps;
filldraw stroke z7e--z8e;  % right stem
pos3(rule_thickness,90); pos4(rule_thickness,90);
pos5(rule_thickness,90); pos6(rule_thickness,90);
x3=x5=x1l; rt x4=rt x6=ceiling(w-.4u)+eps; y3r=y4r=y1; y5l=y6l=y2;
filldraw stroke z3e--z4e;  % upper bar
filldraw stroke z5e--z6e;  % lower bar
penlabels(1,2,3,4,5,6,7,8); endchar;

cmchar "Right semantic bracket ]]";
beginchar(oct"057",7.25u#,body_height#,paren_depth#);
adjust_fit(0,0);
pickup crisp.nib; pos1(rule_thickness,0); pos2(rule_thickness,0);
top y1=h; bot y2=-d; rt x1r=rt x2r=hround(w-2.5u+.5rule_thickness)+1+eps;
filldraw stroke z1e--z2e;  % left stem
pos7(rule_thickness,0); pos8(rule_thickness,0);
top y7=h; bot y8=-d; rt x7r=rt x8r=hround(w-4.75u+.5rule_thickness)+1+eps;
filldraw stroke z7e--z8e;  % right stem
pos3(rule_thickness,90); pos4(rule_thickness,90);
pos5(rule_thickness,90); pos6(rule_thickness,90);
x3=x5=x1l; lft x4=lft x6=ceiling(.4u)-eps; y3r=y4r=y1; y5l=y6l=y2;
filldraw stroke z3e--z4e;  % upper bar
filldraw stroke z5e--z6e;  % lower bar
penlabels(1,2,3,4,5,6,7,8); endchar;

cmchar "Upside-down ampersand";
beginchar(oct"060",14u#,asc_height#,0);
italcorr x_height#*slant-serif_fit# - if serifs: .4u# else: 1.5u# fi;
adjust_fit(0,serif_fit#);
pickup tiny.nib; pos2(slab,-90); x2=4u; bot y2r=-o;
if not hefty:(x,y2l)=whatever[z2r,(w-5u,x_height)]; x2l:=x; fi
if serifs: pos0(fudged.hair,0);
 rt x0r+jut=hround(w-.9u); top y0=x_height;
 pos1(fudged.hair,0); z1=whatever[z0,(.6[x0,x2],0)];
 y1=max(y0-1.5bracket-.2x_height,2/3x_height);
 filldraw stroke z0e---z1e...{left}z2e;  % short diagonal
else: pickup fine.nib; pos1(.25[slab,flare],-15); rt x1r=hround(w-2u);
 y1r=good.y .75[bar_height,x_height]; x1l:=good.x x1l; y1l:=good.y y1l;
 top z2'l=(x2l,tiny.top y2l); bot z2'r=(x2r,tiny.bot y2r);
 filldraw stroke term.e(2',1,right,1,4); fi  % short diagonal and terminal
pickup tiny.nib; numeric slope,theta,reduced_hair;
slope=(h-2vair-slab)/10.5u; theta=angle(-slope,1);
reduced_hair=max(tiny.breadth,hround(fudged.hair if hefty:-2stem_corr fi));
lft x3r=hround .75u; x5=.5[x3r,x6l]; lft x6r=hround .5(w-u);
x3l-x3r=curve-tiny; pos6(reduced_hair,180);
pos5(vair,theta); y5=.5h;
ellipse_set(2l,3l,4l,5l); ellipse_set(2r,3r,4r,5r);
pos7(vair,270); top y7l=h+o; x7=.45[x6r,x8r];
pos8(fudged.stem,30); x8l=good.x(x8l+3.5u-x8); y8r=y6;
ellipse_set(7l,6l,5',5l);
filldraw stroke z2e{left}...z3e{up}...z4e---z5e...{up}z6e
 ...z7e{left}...z8e{down};  % bowls
pos10(slab,90); x10=w-3.5u; bot y10l=-o;
pos9(fudged.stem,angle(z8-z10)-90);
z9=.5[z8,z10]+(1.75u,0) rotated(angle(z8-z10)+90);
filldraw stroke z8e{down}...z9e{z10-z8}...{right}z10e;  % long diagonal
if serifs: pickup crisp.nib; pos10'(slab,90); z10'=z10;
 pos11(fudged.hair,180); rt x11l=hround(w-u); y11=.5bar_height;
 filldraw stroke z10'e{right}...{up}z11e;  % terminal
 numeric inner_jut; if rt x6l+.5u<lft x0l-1.5jut: inner_jut=1.5jut;
 else: rt x6l+.5u=lft x0l-inner_jut; fi
 dish_serif(0,1,a,.6,inner_jut,b,.5,jut)(dark);  % serif
else: pickup fine.nib; pos10'(slab,90); z10'=z10;
 pos11(Vround .5[slab,flare],90);
 rt x11=hround(r-letter_fit-u); bot y11l=vround .07bar_height-o;
 filldraw stroke term.e(10',11,right,1,4); fi  % terminal
currentpicture:=(currentpicture scaled -1) shifted (w,h); % UPSIDE-DOWN!
penlabels(0,1,2,3,4,5,6,7,8,9,10,11); endchar;

% Some arrow gadgets.

def char_negate(suffix c,t,b) = %c is center point; t is top point; b is bottom
pickup rule.nib;
w-x.t=x.b; y.t-y.c=y.c-y.b; draw z.t--z.b;
penlabels(t,c,b); enddef;
def char_center(suffix c) = % find center of type character
x.c=w/2; y.c=.5[-d,h]; enddef;

cmchar "Maps-To relation";
compute_spread(.45x_height#,.55x_height#);
beginchar(oct"120",14u#,v_center(spread#+rule_thickness#));
% this character should be followed immediately by equals or Rightarrow
adjust_fit(0,0); pickup rule.nib;
lft x1=hround u; x6=x2=x1+.5u; x3=x4=x5=x1;
.5[y1,y5]=.5[y2,y6]=math_axis; y5-y3=y4-y1=.24asc_height+eps; 
y1-y5=y2-y6=spread;
draw z3--z4;  % stem
draw z1--z2;  % top bar stub 
draw z5--z6;  % bottom bar stub 
labels(1,2,3,4,5,6); zero_width; endchar;

cmchar "Mmaps-To relation";
compute_spread(.45x_height#,.55x_height#);
beginchar(oct"121",14u#,v_center(2spread#+.5asc_height#+rule_thickness#));
% this character should be followed immediately by equals or Rightarrow
adjust_fit(0,0); pickup rule.nib;
lft x1=hround u; x8=x6=x2=x1+.5u; x7=x3=x4=x5=x1;
.5[y1,y7]=.5[y2,y8]=math_axis; y7-y3=y4-y1=.24asc_height+eps; 
y1-y5=y2-y6=y5-y7=y6-y8=spread;
draw z3--z4;  % stem
draw z1--z2;  % top bar stub 
draw z5--z6;  % middle bar stub 
draw z7--z8;  % bottom bar stub
labels(1,2,3,4,5,6,7,8); zero_width; endchar;

cmchar "Maps-from relation";
compute_spread(.45x_height#,.55x_height#);
beginchar(oct"122",14u#,v_center(spread#+rule_thickness#));
% this character should be preceded immediately by minus or leftarrow
adjust_fit(0,0); pickup rule.nib;
lft x1=hround u; x2=x1+.5u; x3=x4=x1;
y1=y2=math_axis; y1-y3=y4-y1=.24asc_height+eps;
draw z3--z4;  % stem
draw z1--z2;  % bar stub
zero_width; 
currentpicture:= currentpicture xscaled -1;
endchar;

cmchar "Maps-From relation";
compute_spread(.45x_height#,.55x_height#);
beginchar(oct"123",14u#,v_center(spread#+rule_thickness#));
% this character should be preceded immediately by equals or Rightarrow
adjust_fit(0,0); pickup rule.nib;
lft x1=hround u; x6=x2=x1+.5u; x3=x4=x5=x1;
.5[y1,y5]=.5[y2,y6]=math_axis; y5-y3=y4-y1=.24asc_height+eps; 
y1-y5=y2-y6=spread;
draw z3--z4;  % stem
draw z1--z2;  % top bar stub 
draw z5--z6;  % bottom bar stub 
zero_width; 
currentpicture:= currentpicture xscaled -1;
endchar;

cmchar "Mmaps-From relation";
compute_spread(.45x_height#,.55x_height#);
beginchar(oct"124",14u#,v_center(2spread#+.5asc_height#+rule_thickness#));
% this character should be followed immediately by equals or Rightarrow
adjust_fit(0,0); pickup rule.nib;
lft x1=hround u; x8=x6=x2=x1+.5u; x7=x3=x4=x5=x1;
.5[y1,y7]=.5[y2,y8]=math_axis; y7-y3=y4-y1=.24asc_height+eps; 
y1-y5=y2-y6=y5-y7=y6-y8=spread;
draw z3--z4;  % stem
draw z1--z2;  % top bar stub 
draw z5--z6;  % middle bar stub 
draw z7--z8;  % bottom bar stub
currentpicture:= currentpicture xscaled -1;
zero_width; endchar;

cmchar "Negated nonexistant arrow";
compute_spread(.45x_height#,.55x_height#);
beginchar(oct"125",18u#,v_center(spread#+rule_thickness#));
adjust_fit(0,0); pickup crisp.nib;
y3=.24asc_height+eps+math_axis;
char_center(100); top y101=top y3; x101=x100+2u;
char_negate(100,101,102);
zero_width; endchar;

cmchar "Negated nonexistant double arrow";
compute_spread(.45x_height#,.55x_height#);
beginchar(oct"126",18u#,v_center(spread#+rule_thickness#));
adjust_fit(0,0); pickup rule.nib;
y1-y2=spread; .5[y1,y2]=math_axis;
y3=.24asc_height+eps+y1;
char_center(100); top y101=top y3; x101=x100+1.5u; char_negate(100,101,102);
zero_width; endchar;

cmchar "Fill character for stacked arrows";
compute_spread(.45x_height#,.55x_height#);
beginchar(oct"127",14u#,v_center(spread#+.96asc_height#));
italcorr h#*slant-.5u#;
adjust_fit(0,0); pickup rule.nib;
lft x1=hround u-eps; x3=x1; x2=x4=w-x1;
y1=y2; y3=y4; y1-y3=.48asc_height; .5[y1,y3]=math_axis;
draw z1--z2;  % upper bar
draw z3--z4;  % lower bar
labels(1,2,3,4); endchar;
  
cmchar "Left arrow stacked on minus";
compute_spread(.45x_height#,.55x_height#); 
beginchar(oct"130",18u#,v_center(spread#+.96asc_height#)); 
adjust_fit(0,0); pickup crisp.nib; pos1(rule_thickness,90); 
pos2(rule_thickness,90); pos3(bar,0); pos4(bar,0); 
y0=y1=y2=math_axis; x1+.5rule_thickness=hround(w-u); lft 
x0=hround u; y3-y0=y0-y4=.24asc_height+eps; x3=x4=x0+3u+eps; 
pos5(bar,angle(z4-z0)); z5l=z0; pos6(bar,angle(z3-z0)); 
z6l=z0; z9=.381966[.5[z3,z4],z0]; numeric t; path p; 
p=z4r{z9-z4}..z6r; t=xpart(p 
intersectiontimes((0,y2l)--(w,y2l))); x2=xpart point t of p;  
path p; % re-use p 
p=z0..{z4-z9}z4l--subpath (0,t) of\\(z4r{z9-z4}..z6r) 
 --z2l---z1l..z1r---z2r--subpath (t,0) of\\(z3r{z9-z3}..z5r) 
 --z3l{z9-z3}..z0 & cycle;  % arrowhead and stem 
p:=p shifted (0,y2-y4+eps); filldraw p; % top arrow 
pickup rule.nib; draw (z0--z1) shifted (0,y4-y2); % bottom line
penlabels(0,1,2,3,4,5,6,9); endchar; 

cmchar "Right arrow stacked on minus";
compute_spread(.45x_height#,.55x_height#); 
beginchar(oct"131",18u#,v_center(spread#+.96asc_height#)); 
adjust_fit(0,0); pickup crisp.nib; pos1(rule_thickness,90); 
pos2(rule_thickness,90); pos3(bar,0); pos4(bar,0); 
y0=y1=y2=math_axis; x1-.5rule_thickness=hround u; rt 
x0=hround(w-u); y3-y0=y0-y4=.24asc_height+eps; 
x3=x4=x0-3u-eps; pos5(bar,angle(z4-z0)); z5l=z0; 
pos6(bar,angle(z3-z0)); z6l=z0; z9=.381966[.5[z3,z4],z0]; 
numeric t; path p; p=z4l{z9-z4}..z6r; t=xpart(p 
intersectiontimes((0,y2l)--(w,y2l))); x2=xpart point t of p; 
path p; p=z0..{z4-z9}z4r--subpath (0,t) 
of\\(z4l{z9-z4}..z6r) 
 --z2l---z1l..z1r---z2r--subpath (t,0) of\\(z3l{z9-z3}..z5r) 
 --z3r{z9-z3}..z0 & cycle;  % arrowhead and stem 
p:=p shifted (0,y2-y4+eps); filldraw p; % top 
pickup rule.nib; draw (z0--z1) shifted (0,y4-y2); % bottom line
penlabels(0,1,2,3,4,5,6,9); endchar; 

cmchar "Minus stacked on left arrow";
compute_spread(.45x_height#,.55x_height#); 
beginchar(oct"132",18u#,v_center(spread#+.96asc_height#)); 
adjust_fit(0,0); pickup crisp.nib; pos1(rule_thickness,90); 
pos2(rule_thickness,90); pos3(bar,0); pos4(bar,0); 
y0=y1=y2=math_axis; x1+.5rule_thickness=hround(w-u); lft 
x0=hround u; y3-y0=y0-y4=.24asc_height+eps; x3=x4=x0+3u+eps; 
pos5(bar,angle(z4-z0)); z5l=z0; pos6(bar,angle(z3-z0)); 
z6l=z0; z9=.381966[.5[z3,z4],z0]; numeric t; path p; 
p=z4r{z9-z4}..z6r; t=xpart(p 
intersectiontimes((0,y2l)--(w,y2l))); x2=xpart point t of p;  
path p; % re-use p 
p=z0..{z4-z9}z4l--subpath (0,t) of\\(z4r{z9-z4}..z6r) 
 --z2l---z1l..z1r---z2r--subpath (t,0) of\\(z3r{z9-z3}..z5r) 
 --z3l{z9-z3}..z0 & cycle;  % arrowhead and stem 
pickup rule.nib; draw (z0--z1) shifted (0,y2-y4+eps); % top line
p:= p shifted (0,y4-y2); filldraw p; % bottom arrow 
penlabels(0,1,2,3,4,5,6,9); endchar; 

cmchar "Minus stacked on right arrow";
compute_spread(.45x_height#,.55x_height#); 
beginchar(oct"133",18u#,v_center(spread#+.96asc_height#)); 
adjust_fit(0,0); pickup crisp.nib; pos1(rule_thickness,90); 
pos2(rule_thickness,90); pos3(bar,0); pos4(bar,0); 
y0=y1=y2=math_axis; x1-.5rule_thickness=hround u; rt 
x0=hround(w-u); y3-y0=y0-y4=.24asc_height+eps; 
x3=x4=x0-3u-eps; pos5(bar,angle(z4-z0)); z5l=z0; 
pos6(bar,angle(z3-z0)); z6l=z0; z9=.381966[.5[z3,z4],z0]; 
numeric t; path p; p=z4l{z9-z4}..z6r; t=xpart(p 
intersectiontimes((0,y2l)--(w,y2l))); x2=xpart point t of p; 
path p; p=z0..{z4-z9}z4r--subpath (0,t) 
of\\(z4l{z9-z4}..z6r) 
 --z2l---z1l..z1r---z2r--subpath (t,0) of\\(z3l{z9-z3}..z5r) 
 --z3r{z9-z3}..z0 & cycle;  % arrowhead and stem 
pickup rule.nib; draw (z0--z1) shifted (0,y2-y4+eps); % top line
p:=p shifted (0,y4-y2-eps); filldraw p; %bottom 
penlabels(0,1,2,3,4,5,6,9); endchar; 
 
compute_spread(.45x_height#,.55x_height#); 
cmchar "Leftward squiggly arrow";  
beginchar(oct"134",18u#,v_center(spread# + 
rule_thickness#)); 
adjust_fit(0,0); pickup crisp.nib;  
pos1(rule_thickness,90); pos2(rule_thickness,90); 
pos3(bar,0); pos4(bar,0); y0=y1=y2=math_axis; 
x1-.5rule_thickness=hround 11u; rt x0=hround(w-u); 
y3-y0=y0-y4=.24asc_height+eps; x3=x4=x0-3u-eps; 
pos5(bar,angle(z4-z0)); z5l=z0; pos6(bar,angle(z3-z0)); 
z6l=z0; z9=.381966[.5[z3,z4],z0];  
numeric t; path p;  
p=z4l{z9-z4}..z6r; t=xpart(p 
intersectiontimes((0,y2l)--(w,y2l))); x2=xpart point t of p;  
path p; 
p=z0..{z4-z9}z4r--subpath (0,t) of\\(z4l{z9-z4}..z6r) 
 --z2l---z1l..z1r---z2r--subpath (t,0) of\\(z3l{z9-z3}..z5r) 
 --z3r{z9-z3}..z0 & cycle;  % arrowhead and stem 
filldraw p; 
%% now for squiggle              
x12-x11=x13-x12=x14-x13=x15-x14=x16-x15=x1-x16; 
x1-x11=hround (w-2u-x0+x1-.5rule_thickness); 
y11=y13=y15=y0; y12=y16=.5[y0,y3]; 
y14=.5[y4,y0];  
pickup pencircle scaled rule_thickness; 
draw z11---z12---z14---z16---z1; 
currentpicture:=currentpicture xscaled -1 shifted (w,0);
endchar; 
        
cmchar "Multimap symbol";  
beginchar(oct"135",20u#,.8asc_height#,0#);  
adjust_fit(0,0); pickup rule.nib; autorounded; 
numeric circ_diam; circ_diam=5u; 
y2=math_axis; y8=y2+.5circ_diam; rt x2=w-u;  
x6=x2-circ_diam;  
circle_points; draw_circle; 
x9=u+.5rule_thickness; y9=y10=y2; x10=x6-.5rule_thickness; 
draw z9---z10; 
currentpicture:=currentpicture xscaled -1 shifted (w,0);
endchar; 
        
cmchar "Multimap symbol";  
beginchar(oct"136",20u#,.8asc_height#,0#);  
adjust_fit(0,0); pickup rule.nib; autorounded; 
numeric circ_diam; circ_diam=5u; 
y2=math_axis; y8=y2+.5circ_diam; rt x2=w-u;  
x6=x2-circ_diam;  
circle_points; draw_circle; 
x9=w-x10; y9=y10=y2; x10=x6-.5rule_thickness; 
draw z9---z10; 
addto currentpicture also currentpicture xscaled -1 shifted (w,0);
endchar; 

cmchar "Fill character for triple arrows";
compute_spread(.45x_height#,.55x_height#);
beginchar(oct"137",14u#,v_center(2spread#+.5asc_height#+rule_thickness#));
italcorr h#*slant-.5u#;
adjust_fit(0,0); pickup rule.nib;
lft x1=hround u-eps; x5=x3=x1; x2=x4=x6=w-x1;
y1=y2; y3=y4; y5=y6; y1-y3=y3-y5=.48asc_height; y3=math_axis;
draw z1--z2;  % upper bar
draw z3--z4;  % middle bar
draw z5--z6;  % lower bar
labels(1,2,3,4,5,6); endchar;

% Some big operators.

big_sq_cap                      := oct"100";
big_box                         := oct"101";
big_oblong                      := oct"102";
big_parallel                    := oct"103";
big_interleave                  := oct"104";

big_ll_bracket                  := oct"360";
big_rr_bracket                  := oct"370";

iff known big_sq_cap:
cmchar "\textstyle square set intersection sign";
beginchar(big_sq_cap,15u#,0,10/6dh#);
adjust_fit(0,0); pickup pencircle scaled stem;
lft x1=hround u; x2=x1; x4=x5=w-x1;
top y1=eps; bot y2=-d; y4=y2; y5=y1;
draw z2---z1---z5---z4;  % stems and bar
labels(1,2,4,5); endchar;

iff known big_box:
cmchar "\textstyle box sign";
beginchar(big_box,15u#,0,10/6dh#);
adjust_fit(0,0); pickup pencircle scaled stem;
lft x1=hround u; x2=x1; x4=x5=w-x1;
top y1=eps; bot y2=-d; y4=y2; y5=y1;
draw z1---z2---z4---z5---cycle;  % stems and bar
labels(1,2,4,5); endchar;

iff known big_oblong:
cmchar "\textstyle big Dijkstra choice";
beginchar(big_oblong,8u#,0,10/6dh#);
adjust_fit(0,0); pickup pencircle scaled stem;
lft x1=hround u; x2=x1; x4=x5=w-x1;
top y1=eps; bot y2=-d; y4=y2; y5=y1;
draw z1--z2--z4--z5--cycle;  % stems and bar
labels(1,2,4,5); endchar;

iff known big_parallel:
cmchar "\textstyle big parallelism sign";
beginchar(big_parallel,8u#,0,10/6dh#);
adjust_fit(0,0); pickup pencircle scaled stem;
lft x1=hround u; x2=x1; x4=x5=w-x1;
top y1=eps; bot y2=-d; y4=y2; y5=y1;
draw z1---z2;  % left line
draw z4---z5;  % right line
labels(1,2,4,5); endchar;

iff known big_interleave:
cmchar "\textstyle big interleaving sign";
beginchar(big_interleave,9u#,0,10/6dh#);
adjust_fit(u#,u#); pickup pencircle scaled stem;
lft x1=hround 0; x2=x1; 
top y1=eps; bot y2=-d; 
x4=x5=x1+2hround(.5w);
y4=y1;y5=y2;
x6=x7=x1+hround(.5w);
y6=y1;y7=y2;
draw z1---z2;  % left line
draw z4---z5;  % right line
draw z6---z7;  % middle line
labels(1,2,4,5,6,7); endchar;

iff known big_sq_cap:
cmchar "\displaystyle square set union sign";
beginchar(big_sq_cap+8,20u#,0,14/6dh#); padded 1/6dh#;
adjust_fit(0,0); pickup pencircle scaled curve;
lft x1=hround u; x2=x1; x4=x5=w-x1;
top y1=eps; bot y2=-d; y4=y2; y5=y1;
draw z2---z1---z5---z4;  % stems and bar
labels(1,2,4,5); endchar;

iff known big_box:
cmchar "\displaystyle box sign";
beginchar(big_box+8,20u#,0,14/6dh#); padded 1/6dh#;
adjust_fit(0,0); pickup pencircle scaled curve;
lft x1=hround u; x2=x1; x4=x5=w-x1;
top y1=eps; bot y2=-d; y4=y2; y5=y1;
draw z1---z2---z4---z5---cycle;  % stems and bar
labels(1,2,4,5); endchar;

iff known big_oblong:
cmchar "\displaystyle big Dijkstra choice";
beginchar(big_oblong+8,10u#,0,14/6dh#); padded 1/6dh#;
adjust_fit(0,0); pickup pencircle scaled curve;
lft x1=hround u; x2=x1; x4=x5=w-x1;
top y1=eps; bot y2=-d; y4=y2; y5=y1;
draw z1--z2--z4--z5--cycle;  % stems and bar
labels(1,2,4,5); endchar;

iff known big_parallel:
cmchar "\displaystyle big parallelism sign";
beginchar(big_parallel+8,10u#,0,14/6dh#); padded 1/6dh#;
adjust_fit(0,0); pickup pencircle scaled curve;
lft x1=hround u; x2=x1; x4=x5=w-x1;
top y1=eps; bot y2=-d; y4=y2; y5=y1;
draw z1---z2;  % left line
draw z4---z5;  % right line
labels(1,2,4,5); endchar;

iff known big_interleave:
cmchar "\displaystyle big interleaving sign";
beginchar(big_interleave+8,13u#,0,14/6dh#); padded 1/6dh#;
adjust_fit(u#,u#); pickup pencircle scaled curve;
lft x1=hround 0; x2=x1; 
top y1=eps; bot y2=-d; 
x4=x5=x1+2hround(.5w);
y4=y1;y5=y2;
x6=x7=x1+hround(.5w);
y6=y1;y7=y2;
draw z1---z2;  % left line
draw z4---z5;  % right line
draw z6---z7;  % middle line
labels(1,2,4,5,6,7); endchar;

% The command to draw semantic brackets:

def left_semantic_bracket(expr breadth,do_top,do_bot) =
 pickup crisp.nib;
 numeric thickness; thickness=hround breadth;
 pos1(thickness,0); pos2(thickness,0);
 top y1=h; bot y2=1-d; lft x1l=lft x2l=hround(2.5u-.5thickness);
 filldraw stroke z1e--z2e;  % stem1
 pos3(thickness,90); pos4(thickness,90);
 pos5(thickness,90); pos6(thickness,90);
 x3=x5=x1l; rt x4=rt x6=hround(w-.75u+.5thickness);
 y3r=y4r=y1; y5l=y6l=y2;
 if do_top: filldraw stroke z3e--z4e; fi  % upper bar
 if do_bot: filldraw stroke z5e--z6e; fi  % lower bar
 pos7(thickness,0); pos8(thickness,0);
 y7=y1; y8=y2; x7=x8=x1+hround(0.5(w - 3.25u));
 filldraw stroke z7e--z8e;  % stem2 
 penlabels(1,2,3,4,5,6,7,8); enddef;

def right_semantic_bracket(expr breadth,do_top,do_bot) =
 pickup crisp.nib;
 numeric thickness; thickness=hround breadth;
 pos1(thickness,0); pos2(thickness,0);
 top y1=h; bot y2=1-d; rt x1r=rt x2r=hround(w-2.5u+.5thickness);
 filldraw stroke z1e--z2e;  % stem1
 pos3(thickness,90); pos4(thickness,90);
 pos5(thickness,90); pos6(thickness,90);
 x3=x5=x1r; lft x4=lft x6=hround(.75u-.5thickness);
 y3r=y4r=y1; y5l=y6l=y2;
 if do_top: filldraw stroke z3e--z4e; fi  % upper bar
 if do_bot: filldraw stroke z5e--z6e; fi  % lower bar
 pos7(thickness,0); pos8(thickness,0);
 y7=y1; y8=y2; x7=x8=x1-hround(0.5(w - 3.25u));
 filldraw stroke z7e--z8e;  % stem2 
 penlabels(1,2,3,4,5,6,7,8); enddef;

% The semantic brackets:

iff known big_ll_bracket:
cmchar "\big left semantic bracket";
beginchar(big_ll_bracket,8u#,rule_thickness#,2dh#-rule_thickness#);
adjust_fit(1.5u#,0); left_semantic_bracket(rule_thickness,true,true); endchar;

iff known big_ll_bracket:
cmchar "\Big left semantic bracket";
beginchar(big_ll_bracket+1,8.5u#,rule_thickness#,3dh#-rule_thickness#);
adjust_fit(2u#,0); left_semantic_bracket(.25[rule_thickness,stem],true,true); endchar;

iff known big_ll_bracket:
cmchar "\bigg left semantic bracket";
beginchar(big_ll_bracket+2,9u#,rule_thickness#,4dh#-rule_thickness#);
adjust_fit(2.5u#,0); left_semantic_bracket(.5[rule_thickness,stem],true,true); endchar;

iff known big_ll_bracket:
cmchar "\Bigg left semantic bracket";
beginchar(big_ll_bracket+3,9.5u#,rule_thickness#,5dh#-rule_thickness#);
adjust_fit(3u#,0); left_semantic_bracket(.75[rule_thickness,stem],true,true); endchar;

iff known big_ll_bracket:
cmchar "Extensible left semantic bracket---top";
beginchar(big_ll_bracket+4,10u#,rule_thickness#,3dh#-rule_thickness#);
adjust_fit(4u#,0); pickup crisp.nib;
pos1(stem,0); pos2(stem,0);
top y1=h-1; y2=-d-eps; lft x1l=lft x2l=hround(2.5u-.5stem);
filldraw stroke z1e--z2e;  % stem1
pos3(stem,90); pos4(stem,90);
x3=x1l; rt x4=hround(w-.75u+.5stem); y3r=y4r=y1;
filldraw stroke z3e--z4e;  % upper bar
pos7(stem,0); pos8(stem,0);
y7=y1; y8=y2; x7=x8=0.5(x1+x4);
filldraw stroke z7e--z8e;  % stem2
penlabels(1,2,3,4,7,8); endchar;

iff known big_ll_bracket:
cmchar "Extensible left semantic bracket---bottom";
beginchar(big_ll_bracket+5,10u#,rule_thickness#,3dh#-rule_thickness#);
adjust_fit(4u#,0); pickup crisp.nib;
pos1(stem,0); pos2(stem,0);
y1=h+eps; bot y2=1-d; lft x1l=lft x2l=hround(2.5u-.5stem);
filldraw stroke z1e--z2e;  % stem1
pos5(stem,90); pos6(stem,90);
x5=x1l; rt x6=hround(w-.75u+.5stem); y5l=y6l=y2;
filldraw stroke z5e--z6e;  % lower bar
pos7(stem,0); pos8(stem,0);
y7=y1; y8=y2; x7=x8=0.5(x1+x6);
filldraw stroke z7e--z8e;  % stem2
penlabels(1,2,5,6); endchar;

iff known big_ll_bracket:
cmchar "Extensible left semantic bracket---extension module";
beginchar(big_ll_bracket+6,10u#,0,dh#);
adjust_fit(4u#,0); pickup crisp.nib;
pos1(stem,0); pos2(stem,0);
y1=h+1+eps; bot y2=-d-1-eps; lft x1l=lft x2l=hround(2.5u-.5stem);
filldraw stroke z1e--z2e;  % stem1
rt x6=hround(w-.75u+.5stem);
pos7(stem,0); pos8(stem,0);
y7=y1; y8=y2; x7=x8=0.5(x1+x6);
filldraw stroke z7e--z8e;  % stem2
penlabels(1,2,7,8); endchar;

iff known big_rr_bracket:
cmchar "\big right semantic bracket";
beginchar(big_rr_bracket,8u#,rule_thickness#,2dh#-rule_thickness#);
adjust_fit(0,1.5u#); right_semantic_bracket(rule_thickness,true,true); endchar;

iff known big_rr_bracket:
cmchar "\Big right semantic bracket";
beginchar(big_rr_bracket+1,8.5u#,rule_thickness#,3dh#-rule_thickness#);
adjust_fit(0,2u#); right_semantic_bracket(.25[rule_thickness,stem],true,true); endchar;

iff known big_rr_bracket:
cmchar "\bigg right semantic bracket";
beginchar(big_rr_bracket+2,9u#,rule_thickness#,4dh#-rule_thickness#);
adjust_fit(0,2.5u#); right_semantic_bracket(.5[rule_thickness,stem],true,true); endchar;

iff known big_rr_bracket:
cmchar "\Bigg right semantic bracket";
beginchar(big_rr_bracket+3,9.5u#,rule_thickness#,5dh#-rule_thickness#);
adjust_fit(0,3u#); right_semantic_bracket(.75[rule_thickness,stem],true,true); endchar;

iff known big_rr_bracket:
cmchar "Extensible right semantic bracket---top";
beginchar(big_rr_bracket+4,10u#,rule_thickness#,3dh#-rule_thickness#);
adjust_fit(0,4u#); pickup crisp.nib;
pos1(stem,0); pos2(stem,0);
top y1=h-1; y2=-d-eps; rt x1r=rt x2r=hround(w-2.5u+.5stem);
filldraw stroke z1e--z2e;  % stem1
pos3(stem,90); pos4(stem,90);
x3=x1r; lft x4=hround(.75u-.5stem); y3r=y4r=y1;
filldraw stroke z3e--z4e;  % upper bar
pos7(stem,0); pos8(stem,0);
y7=y1; y8=y2; x7=x8=0.5(x1+x4);
filldraw stroke z7e--z8e;  % stem2
penlabels(1,2,3,4,7,8); endchar;

iff known big_rr_bracket:
cmchar "Extensible right semantic bracket---bottom";
beginchar(big_rr_bracket+5,10u#,rule_thickness#,3dh#-rule_thickness#);
adjust_fit(0,4u#); pickup crisp.nib;
pos1(stem,0); pos2(stem,0);
y1=h+eps; bot y2=1-d; rt x1r=rt x2r=hround(w-2.5u+.5stem);
filldraw stroke z1e--z2e;  % stem1
pos5(stem,90); pos6(stem,90);
x5=x1r; lft x6=hround(.75u-.5stem); y5l=y6l=y2;
filldraw stroke z5e--z6e;  % lower bar
pos7(stem,0); pos8(stem,0);
y7=y1; y8=y2; x7=x8=0.5(x1+x6);
filldraw stroke z7e--z8e;  % stem2
penlabels(1,2,5,6,7,8); endchar;

iff known big_rr_bracket:
cmchar "Extensible right semantic bracket---extension module";
beginchar(big_rr_bracket+6,10u#,0,dh#);
adjust_fit(0,4u#); pickup crisp.nib;
pos1(stem,0); pos2(stem,0);
y1=h+1+eps; bot y2=-d-1-eps; rt x1r=rt x2r=hround(w-2.5u+.5stem);
filldraw stroke z1e--z2e;  % stem1
lft x6=hround(.75u-.5stem);
pos7(stem,0); pos8(stem,0);
y7=y1; y8=y2; x7=x8=0.5(x1+x6);
filldraw stroke z7e--z8e;  % stem2
penlabels(1,2,7,8); endchar;

bye