%		estrangelo.mf
% This font was designed by Alan M Stanier	( alan@essex.ac.uk ),
% at Essex University Computer Service, Colchester, Essex CO4 3EA. England.
%
% If you make significant additions or improvements to the font, please email me an updated version
%
%
%	Estrangelo is the alphabet used for writing ancient syriac.
%
% The alphabet had 22 characters, which have been coded as 'a' - 'v'.
%	However, some letters had a variant form, which has been coded as the equivalent uppercase.
%
% The letters forms are those given in Bagster's "Elements of Syriac Grammar"

mg:=1.0;	% CHANGE THIS TO GET DIFFERENT SIZES OF FONT (font size = 10*mg pt)

mode_setup;
tracingtitles := 1;
xpensize#:=mg*0.8pt;
ypensize#:=mg*0.2pt;
bigpensize#:=mg*1pt;
height#:=mg*9.6pt#;
fullwidth#:=mg*8.2pt#;
halfwidth#:=mg*5.3pt#;
quarterwidth#:=mg*3.2pt#;
sixthwidth#:=2.6pt#;
define_pixels(height,fullwidth,halfwidth,quarterwidth,sixthwidth);
def getpen = pickup pencircle xscaled xpensize# yscaled ypensize# rotated 30 enddef;
def getbigpen = pickup pencircle scaled bigpensize# enddef;

beginchar("a",sixthwidth#,height#,0); "aleph";
getpen;
draw (mg*0,mg*28) .. (mg*2,mg*30){right} .. (mg*6,mg*22){down} -- (mg*6,0);
endchar;


beginchar("b",halfwidth#,height#,0); "beth";
getpen;
draw (0,0) -- (mg*7.5,0){right} .. (mg*15,mg*7.5){up} .. (mg*2.5,mg*15){left} -- (0,mg*15);
endchar;


beginchar("B",fullwidth#,height#,0); "Beth";
getpen;
draw (0,mg*5) -- (0,0) -- (mg*15,0){right} .. (mg*30,mg*7.5){up} .. (mg*15,mg*15){left} -- (10,mg*15);
endchar;


beginchar("c",fullwidth#,height#,0); "gamal";
getpen;
draw (0,mg*30) -- (mg*15,mg*30) & flex((mg*15,mg*30),(mg*20,mg*15),(mg*30,0)) & flex((mg*30,0),(mg*27,mg*25),(mg*30,mg*30));
endchar;


beginchar("C",halfwidth#,height#,0); "Gamal";
getpen;
draw flex((0,mg*30),(mg*5,mg*15),(mg*12.5,0)) -- (mg*15,mg*5) & flex((mg*15,mg*5),(mg*13.5,mg*25),(mg*15,mg*30));
endchar;


beginchar("d",quarterwidth#,height#,0); "dalath";
getpen;
draw (0,mg*30) .. (mg*8,mg*25){down} & flex((mg*8,mg*25),(mg*7,mg*20),(mg*3,mg*15),(mg*3,mg*5));
getbigpen;
drawdot(3,1);
endchar;


beginchar("e",fullwidth#,height#,0); "he";
getpen;
draw (mg*7.5,mg*15) .. (0,mg*7.5) .. (mg*7.5,0) .. (mg*15,mg*7.5) .. (mg*7.5,mg*15) -- (mg*30,mg*15) -- (mg*30,0);
endchar;


beginchar("f",halfwidth#,height#,0); "vau";
getpen;
draw (mg*7.5,mg*15) .. (0,mg*7.5) .. (mg*7.5,0) .. (mg*15,mg*7.5) .. (mg*7.5,mg*15);
endchar;


beginchar("g",sixthwidth#,height#,0); "zain";
getpen;
draw (mg*0,mg*12){up} .. (mg*3,mg*15){right} .. (mg*6,mg*11){down} -- (mg*6,0);
endchar;


beginchar("h",halfwidth#,height#,0); "heth";
getpen;
draw flex((0,0),(1*mg,3*mg),(3*mg,10*mg)) & flex((3*mg,10*mg),(6*mg,2*mg),(9*mg,0)) &
	flex((9*mg,0),(12*mg,2*mg),(15*mg,10*mg));
endchar;


beginchar("H",fullwidth#,height#,0); "Heth";
getpen;
draw flex ((0,6*mg),(5*mg,2*mg),(10*mg,0)) & flex((10*mg,0),(11*mg,3*mg),(14*mg,10*mg)) &
	flex((14*mg,10*mg),(18*mg,2*mg),(22*mg,0)) & flex((22*mg,0),(26*mg,2*mg),(30*mg,10*mg));
endchar;


beginchar("i",halfwidth#,height#,0); "teth";
getpen;
draw (15*mg,30*mg) .. (5*mg,10*mg) .. (8*mg,0){right} .. (15*mg,5*mg){up} .. (5*mg,10*mg) .. (0,10*mg);
endchar;


beginchar("I",fullwidth#,height#,0); "Teth";
getpen;
draw (25*mg,30*mg) .. (17*mg,10*mg) .. (23*mg,0){right} .. (30*mg,5*mg){up} .. (17*mg,10*mg) .. (2*mg,10*mg) .. (0,12*mg);
endchar;


beginchar("j",halfwidth#,height#,0); "yud";
getpen;
draw (0,0) -- (12*mg,0) .. (15*mg,5*mg){up} .. (12*mg,10*mg);
endchar;


beginchar("J",halfwidth#,height#,0); "Yud";
getpen;
draw (0,10*mg) -- (0,0) -- (12*mg,0) .. (15*mg,5*mg){up} .. (12*mg,10*mg);
endchar;


beginchar("k",halfwidth#,height#,0); "kaph";
getpen;
draw (0,0) -- (mg*2.5,0) .. (mg*15,mg*7.5){up} .. (mg*2.5,mg*15){left} .. (0,mg*13);
endchar;


beginchar("K",halfwidth#,height#,0); "Kaph";
getpen;
draw (0,15*mg) -- (mg*3,mg*8) .. (mg*10,mg*8) .. (mg*15,mg*12){up} .. (mg*12,mg*15){left} .. (mg*8.5,mg*7.5)
.. (6*mg,0);
endchar;


beginchar("l",halfwidth#,height#,0); "lamad";
getpen;
draw flex((3*mg,30*mg),(5*mg,10*mg),(mg*15,0)) & flex((mg*15,0),(mg*12,mg*25),(mg*15,mg*30));
endchar;


beginchar("L",fullwidth#,height#,0); "Lamad";
getpen;
draw (0,0) -- (30*mg,0) & flex((30*mg,0),(15*mg,15*mg),(15*mg,30*mg));
endchar;


beginchar("m",fullwidth#,height#,0); "mim";
getpen;
draw (0,0) -- (mg*20,0) .. (mg*30,mg*7.5){up} .. (mg*20,mg*15){left} .. (mg*10,0) -- (0,mg*15);
endchar;


beginchar("M",fullwidth#,height#,0); "Mim";
getpen;
draw (0,0) -- (10*mg,10*mg) .. (20*mg,0){right} .. (30*mg,10*mg){up} .. (20*mg,20*mg){left} ..
	(10*mg,10*mg) & flex((10*mg,10*mg),(3*mg,13*mg),(0,20*mg));
endchar;


beginchar("n",quarterwidth#,height#,0); "nun";
getpen;
draw (0,0) -- (6*mg,0) .. (8mg,8*mg){up} .. (6*mg,15*mg);
endchar;


beginchar("N",halfwidth#,height#,0); "Nun";
getpen;
draw flex((0,10*mg),(2*mg,5*mg),(15*mg,0));
endchar;


beginchar("o",halfwidth#,height#,0); "semkath";
getpen;
draw (0,0) -- (8*mg,0){right} .. (15*mg,5*mg){up} .. (12*mg,15*mg){left} .. (8*mg,0){down} -- (7.9*mg,0)
	.. (7.8*mg,0){up} .. (4.5*mg,15*mg){left} .. (mg,0){down};
endchar;


beginchar("O",fullwidth#,height#,0); "Semkath";
getpen;
draw (0,2*mg) .. (23*mg,0){right} .. (30*mg,5*mg){up} .. (27*mg,15*mg){left} .. (23*mg,0){down} -- (22.9*mg,0)
	.. (22.8*mg,0){up} .. (19*mg,15*mg){left} .. (16*mg,0){down};
endchar;


beginchar("p",halfwidth#,height#,0); "'e";
getpen;
draw (0,0) -- (15*mg,0) & flex((15*mg,0),(7*mg,7*mg),(7*mg,15*mg));
endchar;


beginchar("P",halfwidth#,height#,0); "'E";
getpen;
draw flex((0,15*mg),(2.5*mg,3*mg),(mg*7.5,0)) & flex((mg*7.5,0),(mg*6,mg*12.5),(mg*7.5,mg*15));
endchar;


beginchar("q",halfwidth#,height#,0); "pe";
getpen;
draw (0,0) .. (15*mg,7.5*mg){up} .. (7.5*mg,15*mg){left} .. (3*mg,13*mg) .. (0,11*mg) .. (6*mg,11*mg) .. (3*mg,13*mg);
endchar;


beginchar("Q",fullwidth#,height#,0); "Pe";
getpen;
draw (0,5*mg) -- (0,0) -- (15*mg,0){right} .. (30*mg,7.5*mg){up} .. (22.5*mg,15*mg){left} ..
	(18*mg,13*mg) .. (15*mg,11*mg) .. (21*mg,11*mg) .. (18*mg,13*mg);
endchar;


beginchar("r",fullwidth#,height#,0); "tsade";
getpen;
draw (4*mg,26*mg) .. (8*mg,30*mg){right} .. (12*mg,26*mg) .. (8*mg,20*mg) &
	flex((8*mg,20*mg),(16*mg,10*mg),(8*mg,0)) .. (8*mg,0) .. (0,10*mg);
endchar;


beginchar("s",halfwidth#,height#,0); "kuph";
getpen;
draw (0,0) .. (6*mg,0) .. (15*mg,7.5*mg){up} .. (7.5*mg,15*mg){left} .. (3*mg,13*mg){down} .. (6*mg,0);
endchar;


beginchar("S",fullwidth#,height#,0); "Kuph";
getpen;
draw (0,15*mg) -- (0,0) -- (15*mg,0){right} .. (21*mg,0) .. (30*mg,7.5*mg){up} .. (22.5*mg,15*mg){left}
	.. (18*mg,13*mg){down} .. (21*mg,0);
endchar;


beginchar("t",quarterwidth#,height#,0); "rish";
getbigpen;
drawdot (2*mg,25*mg);
getpen;
draw flex((4*mg,20*mg),(8*mg,10*mg),(4*mg,0));
endchar;


beginchar("u",halfwidth#,height#,0); "shin";
getpen;
draw (0,0) .. (6*mg,0);
fill (6*mg,0) .. (15*mg,7.5*mg){up} .. (7.5*mg,15*mg){left} .. (3*mg,13*mg){down} .. (6*mg,0) .. cycle;
endchar;


beginchar("U",fullwidth#,height#,0); "Shin";
getpen;
draw (0,15*mg) -- (0,0) -- (15*mg,0){right} .. (21*mg,0);
fill (21*mg,0) .. (30*mg,7.5*mg){up} .. (22.5*mg,15*mg){left} .. (18*mg,13*mg){down} .. (21*mg,0) .. cycle;
endchar;


beginchar("v",halfwidth#,height#,0); "thau";
getpen;
draw flex((mg*9,mg*30),(mg*14,mg*22),(0,0)) & flex((0,0),(mg*5,mg*2),(mg*15,0));
endchar;


end